SureAI

Forums covering SureAI game titles.

https://sureai.net/forum/

Topic title - Handwerkspunkte modden?

https://sureai.net/forum/viewtopic.php?t=8776

Page 1 of 2
Handwerkspunkte modden? - by sn00ze
Posted: 13.07.2016 12:46
Hallo Zusammen,

kurz und knapp:

Hat jemand eine Ahnung, ob man an irgend einer Stelle in den Spieldateien die Anzahl für Handwerkspunkte, die man je Level erhält, verändern kann?

Ich bin ein Spieler, der sich gerne mit mehreren der Handwerk-Skills beschäftigen möchte, was aber leider nicht so funktioniert, wie ich mir das vorstelle. :cry:

Vielleicht hat ja jemand einen Rat, wie ich das Spielerlebnis für mich anpassen kann :-)

Danke im Voraus & Gruß

Sn00ze
Re: Handwerkspunkte modden? - by Alzucard
Posted: 13.07.2016 12:56
Naja jedes mal, wenn du level up hast kannst du dir ein paar punkte mehr ercheaten ;)

Ich werde trotzdem mal die ganzen dateien durchforsten.
Re: Handwerkspunkte modden? - by sn00ze
Posted: 13.07.2016 13:00
Das ist aber nett, danke :D
Re: Handwerkspunkte modden? - by Winterherz
Posted: 13.07.2016 13:07
Man braucht dafür eigentlich kein Mod, man kann sich das ganze einfach per Konsolenbefehl ercheaten.

Einfach folgendes eingeben:

"set Handwerkspunkte to" und dann die Anzahl der Punkte, die man haben will.
Re: Handwerkspunkte modden? - by Alzucard
Posted: 13.07.2016 13:21
Klar geht das ;)
Aber nicht jeder will sich die Mühe machen xD
Re: Handwerkspunkte modden? - by Alzucard
Posted: 13.07.2016 13:38
Ich finde herraus wie ich Memory Punkte pro level erhöhen kann aber nicht wie ich handwerkspunkte erhöhen kann. Sowass treibt mich in den wahnsinn. Diese dämlichen scripts :/
Re: Handwerkspunkte modden? - by Winterherz
Posted: 13.07.2016 13:41
Also den Befehl schnell eingeben ist eigentlich ja nicht wirklich komplex. :P
Re: Handwerkspunkte modden? - by Alzucard
Posted: 13.07.2016 13:45
Was ich da alles auslese. Äußerst interessant. einfach mal alle affinitäten in den scripts nachgucken. Ganz einfach xD
Außerdem ich will jetzt wissen wo ich den scheiß ändern kann. :dead:

So hab einen teil des scripts gefunden.
[+]
Code Select all
Scriptname _00E_EPUpdateFunctions extends ObjectReference


import math
import _00E_Levelsystem
int MapMarkersDiscoveredCounter = 0
int LocksPickedCounter = 0
int ItemsPickpocketedCounter = 0
int ItemsStolenCounter = 0
int PotionsMixedCounter = 0
int PoisonsMixedCounter = 0
int ArmorMadeCounter = 0
int WeaponsMadeCounter = 0
int SoulsTrappedCounter = 0
int MagicItemsMadeCounter = 0
int IntimidationsCounter = 0




Event OnInit()
	if Self == Game.GetPlayer() as ObjectReference 
		RegisterForSingleUpdate(2.0)
	Endif
EndEvent

Event OnUpdate()

	if MapMarkersDiscoveredCounter < Game.QueryStat("Locations Discovered")
		_00E_Player_sEPGained_Discovery.Show()
		GiveEXP(40)
		MapMarkersDiscoveredCounter += 1
		;Debug.Notification("Nach ausführung:" + MapMarkersDiscoveredCounter)
	EndIf

	if LocksPickedCounter < Game.QueryStat("Locks Picked")
		_00E_Player_sEPGained_LockPicked.Show()
		GiveEXP(15)
		LocksPickedCounter += 1
	EndIf

	;if ItemsPickpocketedCounter < Game.QueryStat("Items Pickpocketed")
	;	Debug.Notification("Gegenstand aus Tasche entwendet gestohlen! Beutelschlitzer!")
	;	GiveEXP(1)
	;	ItemsPickpocketedCounter += 1
	;EndIf
	
	;if ItemsStolenCounter < Game.QueryStat("Items Stolen")
	;	Debug.Notification("Gegenstand gestohlen!")
	;	GiveEXP(1)
	;	ItemsStolenCounter += 1
	;EndIf
	
	if PotionsMixedCounter < Game.QueryStat("Potions Mixed")
		_00E_Player_sEPGained_PotionMixed.Show()
		GiveEXP(3)
		PotionsMixedCounter += 1
	EndIf
	
	if PoisonsMixedCounter < Game.QueryStat("Poisons Mixed")
		_00E_Player_sEPGained_PoisonMixed.Show()
		GiveEXP(3)
		PoisonsMixedCounter += 1
	EndIf
	
	if  ArmorMadeCounter < Game.QueryStat("Armor Made")
		_00E_Player_sEPGained_ArmorMade.Show()
		GiveEXP(20)
		ArmorMadeCounter += 1
	EndIf
	
	if WeaponsMadeCounter < Game.QueryStat("Weapons Made")
		_00E_Player_sEPGained_WeaponsMade.Show()
		GiveEXP(20)
		WeaponsMadeCounter += 1
	EndIf
	
	if SoulsTrappedCounter < Game.QueryStat("Souls Trapped")
		_00E_Player_sEPGained_SoulCaptured.Show()
		GiveEXP(10)
		SoulsTrappedCounter += 1
	EndIf
	
	if MagicItemsMadeCounter < Game.QueryStat("Magic Items Made")
		_00E_Player_sEPGained_MagicItemMade.Show()
		GiveEXP(30)
		MagicItemsMadeCounter += 1
	EndIf
	
	if IntimidationsCounter < Game.QueryStat("Intimidations")
		_00E_Player_sEPGained_Intimidations.Show()
		GiveEXP(50)
		IntimidationsCounter += 1
	EndIf
	
	if PlayerEXP.GetValue() >= 120 && ShowEXPMessage == False
		Message.ResetHelpMessage("Empty")
		_00E_Tutorial_EPSystem.ShowAsHelpMessage("Empty", 4.0, 3.0, 1)
		ShowEXPMessage = true
	EndIf
	
	
	;if Talentpoints.GetValue() != 0 && Utility.RandomInt(0, 20) > 19 && PlayerLevel.GetValue() >= 2
	;	Message.ResetHelpMessage("Shout")
	;	_00E_MQP03_Tutorial_Talentpoints.ShowAsHelpMessage("Shout", 5.0, 1, 1)
	;EndIf
	
	Actor PlayerActor = PlayerRef as Actor

	
	if Arkanistenfieber.GetValue() >= 100 && isdead == false
		PlayerActor.Kill()
		_00E_Player_sArcaneFever_Death.Show()
		isdead = true
		;Arkanistenfieber.SetValue(0)
	elseif Arkanistenfieber.GetValue() >= 90 && Utility.RandomInt(0, 20) > 19 && isdead == false
		_00E_Player_sArcaneFever_Critical.Show()
	ElseIf Arkanistenfieber.GetValue() >= 40 && PlayerActor.HasSpell(_00E_Arkanistenfieber40) == 0 && isdead == false
		PlayerActor.AddSpell(_00E_Arkanistenfieber40,0)
		_00E_Player_sArcaneFever_Worsen.Show()
	ElseIf Arkanistenfieber.GetValue() >= 70 && PlayerActor.HasSpell(_00E_Arkanistenfieber70) == 0 && isdead == false
		PlayerActor.AddSpell(_00E_Arkanistenfieber70,0)
		_00E_Player_sArcaneFever_Worsen.Show()
	EndIf
	
	if PlayerActor.HasSpell(_00E_Arkanistenfieber40) == 1 && Arkanistenfieber.GetValue() < 40 && isdead == false
		PlayerActor.RemoveSpell(_00E_Arkanistenfieber40)
		_00E_Player_sArcaneFever_Cure.Show()
	EndIf
	
	if PlayerActor.HasSpell(_00E_Arkanistenfieber70) == 1 && Arkanistenfieber.GetValue() < 70 && isdead == false
		PlayerActor.RemoveSpell(_00E_Arkanistenfieber70)
		_00E_Player_sArcaneFever_Cure.Show()
	EndIf

	
	if !PlayerActor.IsInCombat()
		;debug.notification("Player isn't in combat. Try to remove combat soundtrack")
		_00E_Music_Combat_Exotic.Remove()
		_00E_Music_Combat_Regular.Remove()
		_00E_Music_Combat_RegularTest.Remove()
		_00E_Music_Combat_Regular2.Remove()
	endif
	
	if CurrentLevel < PlayerActor.GetLevel()
		CurrentLevel += 1
		ResetHeroMenuHelpBox = false
	endif
	
	if (CurrentLevel <= MaxLevelToDisplayHeroMenuMessage) && (ResetHeroMenuHelpBox == false) && (PlayerActor.GetLevel() >= 2)
		Message.ResetHelpMessage("Empty")
		_00E_Tutorial_HeroMenue.ShowAsHelpMessage("Empty", 7, 30, 2)
		
		;Debug.MessageBox("Test")
		ResetHeroMenuHelpBox = true
	endif
	
	RegisterForSingleUpdate(3.4) ; erscheint mir angemessener Wert, an scriptintensiven Spielabschnitten evtl. auf 3-4 erhöhen!
EndEvent


Event OnDeath(Actor akKiller)
	if Game.GetPlayer().IsInCombat()
		Debug.Notification("Idiot!")
		GiveEXP(1000)
	EndIf
EndEvent


Function GiveEXP(int ToGive)

		RewardEPDisplay.SetValueInt(ToGive)
		Debug.Notification("+" + RewardEPDisplay.GetValueInt() + "EP")
		PlayerExp.Mod(ToGive)
		PlayerNeededExp.SetValue(pow(PlayerLevel.GetValueInt(), EXPMultSlope.GetValue()) * EXPMult.GetValue())
		int iLevelUpCount = CheckForLevelUp(PlayerExp, PlayerLevel, EXPMult, EXPMultSlope)

		;Debug.Notification("" + PlayerExp.GetValueInt() + " / " + PlayerNeededExp.GetValueInt() + "EP")

		while(iLevelUpCount > 0)
			UILevelUp.Play(Game.GetPlayer())
			;_00E_Track_Success.Add()
			iMessage = _00E_Levelup.show(PlayerLevel.GetValueInt())
			Game.SetPlayerLevel(PlayerLevel.GetValueInt())
			int TalentPointsInt = TalentPoints.GetValueInt() + 1
			TalentPoints.SetValue(TalentPointsInt)
			Game.GetPlayer().SetAV("dragonsouls", TalentPoints.GetValueInt())
			Lernpunkte.SetValue(Lernpunkte.GetValue()+5)			
			Handwerkspunkte.SetValue(Handwerkspunkte.GetValue()+3)
		
				;Game.AddPerkPoints(1)
			if iMessage == 0 
				Game.GetPlayer().SetActorValue("Health", Game.GetPlayer().GetBaseAV("Health")+9)
			endif
			if iMessage == 1 
				Game.GetPlayer().SetActorValue("Magicka", Game.GetPlayer().GetBaseAV("Magicka")+8)
			endif
			if iMessage == 2 
				Game.GetPlayer().SetActorValue("Stamina", Game.GetPlayer().GetBaseAV("Stamina")+11)
			endif

			iLevelUpCount -= 1
		endWhile
		


EndFunction
Dort kann man auch einstellen wie viel Leben usw.
C:\Program Files (x86)\Steam\steamapps\common\Skyrim\Data\Scripts\Source\_00E_EPUpdateFunctions.psc

ich würde empfehlen das ding mit notepad zu öffnen. Nur zur info ich habs nicht getestet. kann also sein, dass noch andere dinge geändert werden müssen.
Re: Handwerkspunkte modden? - by sn00ze
Posted: 13.07.2016 13:54
Danke für die Hilfe!

Also, wenn ich das richtig lese, muss ich einfach hier:

Handwerkspunkte.SetValue(Handwerkspunkte.GetValue()+3)

die 3 z.B. zur 5 machen, richtig?
Re: Handwerkspunkte modden? - by Alzucard
Posted: 13.07.2016 13:57
Das bezweifel ich stark. Diese Textzeilen kommen noch in vielen anderen Scripts vor. Ich kenn mich leider nicht gut genug damit aus um es dir näher zu erklären. Du weiß nun nahc was du suchen musst zumindest. Ich würde auch gerne 5 Handwerkspunkte pro level bekommen oder sogar mehr. Naja ich werd weiter forschen und probieren.

Ich werds nachher mal testen. Zuerst muss ich erstmal was essen ^^

PS: leg dir ne Sicherung vom ganzen an sonst musste eventuall alles neuinstallieren.
All times are UTC
Page 1 of 2
Powered by phpBB® Forum Software © phpBB Limited