SureAI

Forums covering SureAI game titles.

https://sureai.net/forum/

Topic title - Download zu Nehrim Expanded

https://sureai.net/forum/viewtopic.php?t=6491

Page 23 of 55
Re: Download zu Nehrim Expanded - by Tealor Arantheal
Posted: 21.09.2014 20:51
Kleines Update

Hab schon wieder eine Datei hochgeladen, da mir noch etwas eingefallen ist, um die Fertigkeit "Handelsgeschick" interessanter zu machen.
In Nehrim gibt es eine handvoll ausgewählter Verkäufer deren Kaufkraft bei über 1000 liegt.
Aber meistens trifft man nur auf Händler mit einer Kaufkraft zwischen 200 und 500.

Nun wirkt sich das Handelsgeschick des Spielers auch auf die Kaufkraft aller Händler aus.

Handelsgeschick 25 = +100 Kaufkraft
Handelsgeschick 50 = +200 Kaufkraft
Handelsgeschick 75 = +300 Kaufkraft
Handelsgeschick 100 = +400 Kaufkraft

Also insgesamt können die Händler einen Bonus auf die Kaufkraft von 1000 bekommen, wenn man fleißig in das Handelsgeschick investiert.
Dadurch lassen sich dann teure Gegenstände mit weitaus weniger Verlust verscherbeln.

Hier das Skript dafür:
[+]
Code Select all
scn AllgemeinesHandelScript

short Anfangswert
short NeuesHaendlerGold

Begin GameMode
	if Anfangswert == 0 && GetBarterGold != 0
		Set Anfangswert to GetBarterGold
	endif
	if (GetBarterGold != (Anfangswert + 100)) && Player.GetBaseAV Mercantile >= 25 && Player.GetBaseAV Mercantile < 50
		Set NeuesHaendlerGold to Anfangswert + 100
		SetBartergold NeuesHaendlerGold
	elseif (GetBarterGold != (Anfangswert + 300)) && Player.GetBaseAV Mercantile >= 50 && Player.GetBaseAV Mercantile < 75
		Set NeuesHaendlerGold to Anfangswert + 300
		SetBartergold NeuesHaendlerGold
	elseif (GetBarterGold != (Anfangswert + 600)) && Player.GetBaseAV Mercantile >= 75 && Player.GetBaseAV Mercantile < 100
		Set NeuesHaendlerGold to Anfangswert + 600
		SetBartergold NeuesHaendlerGold
	elseif (GetBarterGold != (Anfangswert + 1000)) && Player.GetBaseAV Mercantile >= 100
		Set NeuesHaendlerGold to Anfangswert + 1000
		SetBartergold NeuesHaendlerGold
	endif
End
Simpel aber effektiv. Leider haben ein paar Händler und Lehrer die etwas verkaufen können ein eigenes Skript, in welchen dieser Zusatz eingebaut werden musste.
Diese Skripts (ZauberhändlerSkripts) werden auch oft global benutzt und auch von Personen die eigentlich nichts verkaufen.
Das sollte allerdings nicht weiter schlimm sein, da man deren Kaufkraft ohnehin niemals zu Gesicht bekommt.

Diese Version ist leider noch kein Bestandteil des Komplettpakets.
Re: Download zu Nehrim Expanded - by Tealor Arantheal
Posted: 22.09.2014 17:07
Weiteres Update

Das Problem mit dem Einfrieren und anschließendem Wiederauftauen durch erneutem Eistreffer wurde wie hier beschrieben gelöst.
Re: Download zu Nehrim Expanded - by Tealor Arantheal
Posted: 22.09.2014 22:09
Betrifft nur Komplettpaket

Das Komplettpaket enthält nun auch die neueste Version von NE.
Re: Download zu Nehrim Expanded - by ZickiBiT
Posted: 22.09.2014 23:15
Mir ist aufgefallen das beim Level Aufstieg die Meldung "das man aufsteigen kann und das Tagebuch öffnen soll" ziemlich alle anderen Status Meldungen überpriorisiert. Das ist aus vielerlei Hinsicht ungünstig da andere Statusmeldungen dann komplett flöten gehen bzw. gar nicht mehr erscheinen. Geschickter wäre es doch das maximal alle Minute einmal einzublenden das Dreieckssymbol am rechten oberen Bildschirmrad bleibt ja immer sichbar.
So würde man u.a. auch wieder die anderen Meldungen zu Geischt bekommen. Klar kann man Level aufsteigen dann ist das Thema vom Tisch vielleicht möchte man das aber zu dem Zeitpunkt aber noch gar nicht um z.B. mehr zu sammeln um durch verzerren von Kräutern seinen Alchemiewert weiter zu erhöhen um den vollen +5 Wert beim Levelaufstieg zu erhalten.

Würde ich als sinnvoll erachten vielleicht hat da jemand eine Idee :idea: wie man da einen Timer einsetzt

Alchemie beim Levelaufsteig Lehrling (25) steht in der Textskillbox das man ab nun Feuerstellen zum Kochen benutzen kann das ist falch das geht bereits ab Alchemiewert 20. Is ja ruckzuck geändert und nurn kleiner Schönheitsfehler.
Re: Download zu Nehrim Expanded - by Tealor Arantheal
Posted: 23.09.2014 00:57
ZickiBiT wrote:
Alchemie beim Levelaufsteig Lehrling (25) steht in der Textskillbox das man ab nun Feuerstellen zum Kochen benutzen kann das ist falch das geht bereits ab Alchemiewert 20.
Das stimmt.
Allerdings habe ich das bewusst so eingebaut, als Erinnerung sozusagen ^^
Ansonsten würde sich die Meldung kaum von der in Oblivion unterscheiden, wie soviele andere.
Diese Meldungen sind fix an das Fertigkeitslevel gebunden (in dem Fall 25).
Die anderen Meldungen bezüglich "Bier brauen und Wein keltern" sind da auch recht ungenau. Genaueres findet man ohnehin in der Alchemie-Statistik des Tagebuchs.
Zuvor war da überhaupt keine Meldung. Wenn dir das lieber ist, dann lösch einfach die Skilleinträge mit TESIVEdit und beim nächsten Mal, wenn du bei einem Trainer die Fertigkeit erhöhst kommt eine Textskillbox in der "OBLIVION STANDARDNACHRICHT" drinnen steht.
Betrachte die Meldung also als Platzhalter, der nicht absolut genau sein muss.
Zwar hatte ich vor individuelle Meldungen zu schreiben, aber da ist auch diese verdammte Zeichenbegrenzung...
Vielleicht ändere ich noch was daran...
ZickiBiT wrote:
Is ja ruckzuck geändert und nurn kleiner Schönheitsfehler.
Sowas ist schnell gesagt, wenn man nicht berücksichtigt, dass ich auch ein 400 MB-Paket warten muss.
Und das mit einen Upspeed von nur 30 KB/s. ;)
ZickiBiT wrote:
Geschickter wäre es doch das maximal alle Minute einmal einzublenden
Dieser Vorschlag gefällt mir allerdings sehr gut.
Bisher war mir das immer recht egal, da ich ohnehin nicht lange ein Level Up stehen ließ.
Jetzt wo ich mir das genauer angesehen hab, ist mir aufgefallen das für diesen Zustand sogar ein eigener Message Spam geschrieben wurde inklusive dazugehörigem Timer.
Der funktioniert allerdings nicht richtig, weil die Nachricht AUSSERHALB des zu erreichendem Zeitfensters geschmissen wird, demnach also jedes Frame ^^
Genauer gesagt gibt es sogar zwei Nachrichten, wobei beide alle 8 Sekunden angezeigt werden.

Ich hab jetzt beide Nachrichten in die Timerabfrage gestellt und den ersten Timer auf 64 Sekunden gestellt.
Die zweite Nachricht kommt 8 Sekunden nach der Ersten, dann wiederholt sich das Spiel (mit 64 Sekunden).

ACHTUNG: Die mit Nehrim Expanded kompatible "Nehrim XP Progress Bar.esp" musste ebenfalls geändert werden, da auch die das fehlerhafte Coding für den Messagespam hat.
Zu finden bei den Patch-ESPs.
Re: Download zu Nehrim Expanded - by Tealor Arantheal
Posted: 23.09.2014 16:04
Update

Weil ich motiviert war hab ich diese Platzhaltermeldungen beim Levelaufstieg etwas individualisiert.
Ich hoffe es passt, da ich mit TESIVEdit alles ratzfatz aus dem Editor reinkopieren konnte.
Überprüft habe ich es noch nicht :P
Viel Besseres ist dabei wahrscheinlich nicht rausgekommen, aber immerhin lesen sich die Meldungen jetzt nicht mehr ganz so eintönig.

Beim Durchgehen der Skills sind mir noch ein paar Ideen zu Beschwörung und Wortgewandtheit eingefallen.

Hat man Beschwörung auf 50 kann man zwei Kreaturen gleichzeitig beschwören. Bei 100 sind es sogar drei.
Viel hat man davon nicht, da man kaum Erfahrungspunkte bekommt wenn man sich überall raushauen lässt.
Allerdings sollte das Spiel für reine Beschwörer nun interessanter sein.

In die Wortgewandtheit wurde nun ein Fallout 3-Exploit eingebaut :mrgreen:
Wenn man sich einer Verhaftung widersetzt, besteht die Möglichkeit (ab Wortgewandtheit 25), dass man die Wache überreden kann das Kopfgeld welches auf den Spieler ausgesetzt ist zu streichen.
Das passiert allerdings vollautomatisch und zufällig.
Steigert man die Fertigkeit erhöht sich auch das Kopfgeld das sich streichen lässt.
Bei 25 kann man maximal 100 zu einer 50:50-Chance streichen lassen.
Bei 100 kann man sogar 1040 Kopfgeld mit einer 25%-Chance streichen lassen.
Der Exploit besteht darin, dass man bei einem Fehlschlag und der daraufolgende Aufgabe im nächsten Gespräch wieder die Möglichkeit hat den Wächter zu überreden.
Ebenso konnte man in Fallout 3 vor jeder Sprachherausforderung speichern und wieder laden. ^^
Das überarbeitete Coding für das Strafsystem hab ich mir ausgedacht.
[+]
Code Select all
SCN StrafsystemQuestScript

Short Tage
Short Back
Short Bezahlen
Short KannNichtZahlen
Short StrafeEntrichtet
Short StraferlassRueckkehrpunkt
Short GnadenSchalter
Short ZeigtGnade
Float ZufallDerGnade
Float fQuestDelayTime
Float Timer
float fpos

Begin MenuMode
Set fQuestDelayTime to 0.1

if ( MenuMode 1009 == 1 )
if GnadenSchalter
	Set GnadenSchalter to 0
	 if ( (Tage - GameDaysPassed) <= 0 )
		Set ZufallDerGnade to Rand 1 100
		if Player.GetBaseAV SpeechCraft >= 25 && Player.GetBaseAV SpeechCraft < 50
			if Player.GetCrimeGold <= 100 && ZufallDerGnade >= 50
				Set ZeigtGnade to 1
				Set Tage to (GameDaysPassed + 3)
			else
				Set ZeigtGnade to 0
			endif
		elseif Player.GetBaseAV SpeechCraft >= 50 && Player.GetBaseAV SpeechCraft < 75
			if Player.GetCrimeGold <= 100 && ZufallDerGnade >= 45
				Set ZeigtGnade to 1
				Set Tage to (GameDaysPassed + 3)
			elseif Player.GetCrimeGold > 100 && Player.GetCrimeGold <= 250 && ZufallDerGnade >= 65
				Set ZeigtGnade to 1
				Set Tage to (GameDaysPassed + 3)
			else
				Set ZeigtGnade to 0
			endif
		elseif Player.GetBaseAV SpeechCraft >= 75 && Player.GetBaseAV SpeechCraft < 100
			if Player.GetCrimeGold <= 100 && ZufallDerGnade >= 35
				Set ZeigtGnade to 1
				Set Tage to (GameDaysPassed + 3)
			elseif Player.GetCrimeGold > 100 && Player.GetCrimeGold <= 250 && ZufallDerGnade >= 55
				Set ZeigtGnade to 1
				Set Tage to (GameDaysPassed + 3)
			elseif Player.GetCrimeGold > 250 && Player.GetCrimeGold <= 500 && ZufallDerGnade >= 70
				Set ZeigtGnade to 1
				Set Tage to (GameDaysPassed + 3)
			else
				Set ZeigtGnade to 0
			endif
		elseif Player.GetBaseAV SpeechCraft >= 100
			if Player.GetCrimeGold <= 100 && ZufallDerGnade >= 25
				Set ZeigtGnade to 1
				Set Tage to (GameDaysPassed + 3)
			elseif Player.GetCrimeGold > 100 && Player.GetCrimeGold <= 250 && ZufallDerGnade >= 45
				Set ZeigtGnade to 1
				Set Tage to (GameDaysPassed + 3)
			elseif Player.GetCrimeGold > 250 && Player.GetCrimeGold <= 500 && ZufallDerGnade >= 60
				Set ZeigtGnade to 1
				Set Tage to (GameDaysPassed + 3)
			elseif Player.GetCrimeGold > 500 && Player.GetCrimeGold <= 1040 && ZufallDerGnade >= 75
				Set ZeigtGnade to 1
				Set Tage to (GameDaysPassed + 3)
			else
				Set ZeigtGnade to 0
			endif
		else
			Set ZeigtGnade to 0
		endif
	endif
endif
		
if ( StraferlassRueckkehrpunkt == 0 )

	StraferlassRueckkehrMarkerRef.moveto player
	StraferlassRueckkehrMarkerRef.disable
	StraferlassRueckkehrMarkerRef.enable

	set fpos to player.getpos x
	StraferlassRueckkehrMarkerRef.setpos x fpos

	set fpos to player.getpos y
	StraferlassRueckkehrMarkerRef.setpos y fpos

	set fpos to player.getpos z
	StraferlassRueckkehrMarkerRef.setpos z fpos

endif					
endif

End

Begin GameMode
Set fQuestDelayTime to 0.1

if GnadenSchalter == 0
	Set GnadenSchalter to 1
endif

;///////////////////////////////////////////[Straferlass]////////////////////////////////////////////////
if ( Bezahlen == 1 )
	if ( Player.GetCrimeGold <= Goldstand )
		Player.RemoveItem "Gold001" CrimeGold 
		Set StraferlassRueckkehrpunkt to 1
		Set StrafeEntrichtet to 1
		Set Bezahlen to 0
		Player.SetCrimeGold 0
	endif
endif

if (	Player.GetInCell StraferlassZelle == 1 )
	Player.SetCrimeGold 0
	;Player.PayFine
	Set Back to 1
	Player.MoveTo "StraferlassRueckkehrMarkerRef"
endif

if ( StrafeEntrichtet == 1 )
if ( Back == 1 )
	if (	Player.GetInCell StraferlassZelle != 1 )
		Set StrafeEntrichtet to 0
		Set StraferlassRueckkehrpunkt to 0	
		Set Back to 0
	endif
endif
endif

;////////////////////////////[Kann Strafe nicht zahlen/ Kann Zahlen]//////////////////////// Auswahl wird auf Gefängnis und Widersetzen reduziert.
if ( KannNichtZahlen == 0 )
	if ( Player.GetCrimeGold > Goldstand )
		Set KannNichtZahlen to 1
	endif
endif

if ( KannNichtZahlen == 1 )
	if ( Player.GetCrimeGold < Goldstand )
		Set KannNichtZahlen to 0
	endif
endif

End
Ich dachte mir, dass Wortgewandtheit ohnehin eine Fähigkeit ist mit der (zumindestens im Spiel) kaum jemand etwas anzufangen weiß und offenbar stieß ich da auf Zustimmung :mrgreen:
Deshalb widme ich dieser Fertigkeit voller Stolz diesen Exploit XD

Um das Ganze aber nicht zu sehr wie einen Cheat wirken zu lassen hat man nur einmal alle 3 Tage die Möglichkeit eine solche Überredung glücken zu lassen.
Re: Download zu Nehrim Expanded - by Tealor Arantheal
Posted: 23.09.2014 22:06
Inzwischen hab ich auch Gelegenheit gefunden mit den neuen Fischen herumzublödeln ^^
Re: Download zu Nehrim Expanded - by ZickiBiT
Posted: 24.09.2014 09:55
Die armen Fische rofl. Wurden die letzten Änderungen "Messagespam Levelaufstieg" schon hochgeladen weil bei mir tut sich da nichts
... nur ne Frage ich habe Zeit wollte das nur wissen.
Übrigens sollte dieser Link http://www.nexusmods.com/oblivion/mods/44618/? diverse Probleme lösen die Probleme haben mit Liquid Water und schwarzen Shadern. Ich probiers nicht mehr hört sich aber vernünpftig an !
Re: Download zu Nehrim Expanded - by Tealor Arantheal
Posted: 24.09.2014 10:57
ZickiBiT wrote:
Wurden die letzten Änderungen "Messagespam Levelaufstieg" schon hochgeladen weil bei mir tut sich da nichts
Yep... Funktioniert bei mir einwandfrei.

Gorin wrote:
Allgemeiner Tipp: Verkauf anfangs niemals mehrere Gegenstände auf einmal, sondern immer einen Gegenstand nach dem anderen, selbst wenn du über 100 Stück von einem Gegenstand hast.
So steigert sich dein Handelsgeschick nämlich viel schneller
Um nochmal auf das zurückzukommen.
Ich frage mich noch immer was sich Bethesda bei diesem Schwachsinn gedacht hat. :dead:
Glücklicherweise kann man ja skripten:
[+]
Code Select all
scn HandelsgeschickQUESTscript

float fquestdelaytime
float AlterGoldstand
short AlterFertigkeitslevel
short UnterhaltungsCheck


Begin GameMode
	set fquestdelaytime to 1.5

	if UnterhaltungsCheck
		set UnterhaltungsCheck to 0
	endif
End


Begin MenuMode
set fquestdelaytime to 0.01


If (Menumode 1009 == 1)
	Set UnterhaltungsCheck to 1
	Set AlterGoldstand to player.getgold
	Set AlterFertigkeitslevel to Player.GetBaseAV Mercantile
	return
elseif (UnterhaltungsCheck == 1 && MenuMode 1008 == 1)
else
	return
endif

If (player.GetGold > AlterGoldstand) && Player.GetBaseAV Mercantile < 100
	if GetLastTransactionQuantity > 1
		Set AlterGoldstand to GetSkillUseIncrement Mercantile 0 * (GetLastTransactionQuantity - 1)
		ModPlayerSkillExp Mercantile AlterGoldstand
		if AlterFertigkeitsLevel < 25 && Player.GetBaseAV Mercantile >= 25
			Set AlterGoldStand to Player.GetBaseAV Mercantile - AlterFertigkeitslevel
			ModPCMiscStat 2 AlterGoldstand
			Playsound UIStatsSkillUP
			Message "Eure/Euer Handelsgeschick hat sich verbessert"
			Messagebox "Verhandeln, feilschen, Angebote vergleichen - das alles läuft nur auf ein Ziel hinaus:  Den besten Preis für die Ware zu erzielen. Ihr seid nun Lehrling des Kaufhandels. Wenn Ihr einen Gegenstand verkauft, ist es nunmehr egal, ob dieser beschädigt ist. Außerdem werden Händler nun etwas mehr Kaufkraft zur Verfügung stellen."
		elseif AlterFertigkeitsLevel < 50 && Player.GetBaseAV Mercantile >= 50
			Set AlterGoldStand to Player.GetBaseAV Mercantile - AlterFertigkeitslevel
			ModPCMiscStat 2 AlterGoldstand
			Playsound UIStatsSkillUP
			Message "Eure/Euer Handelsgeschick hat sich verbessert"
			Messagebox "Als Geselle des Kaufhandels könnt Ihr jeden Gegenstand bei jedem Händler kaufen oder losschlagen, auch wenn der normalerweise nicht mit dieser Art Waren handelt. Darüber hinaus werden Händler noch mehr Kaufkraft zur Verfügung stellen."
		elseif AlterFertigkeitsLevel < 75 && Player.GetBaseAV Mercantile >= 75
			Set AlterGoldStand to Player.GetBaseAV Mercantile - AlterFertigkeitslevel
			ModPCMiscStat 2 AlterGoldstand
			Playsound UIStatsSkillUP
			Message "Eure/Euer Handelsgeschick hat sich verbessert"
			Messagebox "Ihr seid nun Experte des Kaufhandels. Feilscht gut mit den Händlern und Eure Gewinne werden groß sein, denn die Händler stellen Ihnen nun weitaus mehr Kaufkraft zur Verfügung."
		elseif AlterFertigkeitsLevel < 100 && Player.GetBaseAV Mercantile >= 100
			Set AlterGoldStand to Player.GetBaseAV Mercantile - AlterFertigkeitslevel
			ModPCMiscStat 2 AlterGoldstand
			Playsound UIStatsSkillUP
			Set AlterGoldstand to GetPlayerSkillUse Mercantile - (GetPlayerSkillUse Mercantile * 2)
			ModPlayerSkillExp Mercantile AlterGoldstand
			Message "Eure/Euer Handelsgeschick hat sich verbessert"
			Messagebox "Ihr bezeichnet Euch nun zurecht als Kaufhandelsmeister, da Ihr jedem alles ver- und abkaufen könnt, mit Ausnahme dessen, was er am Leibe trägt. Die Händler stellen Ihnen nun außerdem enorm viel Kaufkraft zur Verfügung, in der Hoffnung, dass Ihr die Früchte Eurer Abenteuer mit Ihnen teilt."
		elseif Alterfertigkeitslevel < Player.GetBaseAV Mercantile
			Set AlterGoldStand to Player.GetBaseAV Mercantile - AlterFertigkeitslevel
			ModPCMiscStat 2 AlterGoldstand
			Playsound UIStatsSkillUP
			Message "Eure/Euer Handelsgeschick hat sich verbessert"
		endif
	endif
endif
Set AlterGoldstand to player.getgold
Set AlterFertigkeitslevel to Player.GetBaseAV Mercantile
End
Es gibt nun ein komplett neues System, das berechnet wieviel bei der letzten Transaktion verkauft wurde und dieser Wert wird dann ebenfalls in den Skill mit einberechnet so als ob man alle Stücke einzeln verkauft hat.

Dafür wurde die Geschwindigkeit in der Handelsgeschick gesteigert werden kann drastisch reduziert.
Zuvor war der Wert auf 1 jetzt ist er nur noch auf 0,28.
Re: Download zu Nehrim Expanded - by Tealor Arantheal
Posted: 24.09.2014 14:50
Hier noch zwei Videos von den neuesten Änderungen:


Man sollte allerdings unbedingt berücksichtigen, dass ich hier eine Wortgewandtheit von 100 verwende. Bis dorthin muss man sich erst einmal vorarbeiten.
Ansonsten sei noch zu erwähnen, dass die Möglichkeit auf Gnade bei JEDER Unterhaltung berechnet wird.
Wenn man also Lehrer oder Kaufleute anspricht, wird ebebfalls ermittelt ob eine Wache Gnade walten lassen würde.
Trifft das zu, so hat man die nächsten drei Tage lang die Möglichkeit sich das Kopfgeld von einer Wache streichen zu lassen.
Ansonsten wird einfach wieder berechnet, bis man die Möglichkeit einmal wahr nimmt, danach tritt die Drei-Tage-Regel in Kraft.
Zwar kann man mit Hilfe von warten oder schlafen noch immer einen Exploit aus dieser Funktion machen, allerdings ist er Dank der Drei-Tage-Regel nicht wirklich schlimmer als das Sprachsystem von Fallout 3.


Wenn man den einzelnen Verkauf der im normalen Oblivion notwendig ist heranzieht, so sieht das beinahe schon nach cheaten aus.
Allerdings habe ich es eigenhändig überprüft.
Zuerst gekuckt wie hoch mein Handelsgeschick ist und danach 52 Dunkelpfeile EINZELN verkauft.
Die Änderung am Balken gemerkt und neu geladen.
Diesmal alle 52 auf einmal verkauft und der Balken war identisch (oder etwas höher sofern das keine optische Täuschung war).
Also funktioniert das eigentlich so wie man Handelsgeschick leveln sollte.
Um es dennoch etwas zu verkürzen wurde der Erhöhungswert wie oben beschrieben verringert.
Man sieht im Video auch, dass ich tonnenweise Pfeile verkaufe (das sind alle die ich bisher im Spiel gesammelt habe ^^), demnach spart man sich damit eben nur das Verkaufen von Einzelnen.
Um Handelsgeschick in die Höhe zu treiben, sollte man also massig Zutaten sammeln und verscherbeln.
Denn die wachsen immerhin nach. Wer zu faul zum Ernten ist, kann auch die heilige Handsense verwenden.
All times are UTC
Page 23 of 55
Powered by phpBB® Forum Software © phpBB Limited