Bei 1060 waren PC und NPC "behaftet", jetzt bei 1061 sind nur noch die NPC's betroffen, sehr sehr merkwürdig.
Die andere Sache mit den appendet folder name hat sich in 1061 leider verschlimmbessert,
aber dafür gibts eine Lösung.
Wenn Setup, vom Launcher runtergeladen und ein Ebene höher platziert wird, erscheint keine "wpSelectDir page" mehr.
Falls Setup von irgendwo anders gestartet wird erscheint "wpSelectDir" und der Next-button ist so lange angeraut bis man sich wirklich im Nehrim-install-folder befindet. Siehe Zeile 3 in der CODE Sektion.
Außerdem ist der Nehrim-install-folder-name relativ, z.B. kann Nehrim auch unter xyz\OTC-Nehrim installiert sein.
Wichtig:
AppName und AppVerName müssen genau so wie angegeben übernommen werden.
Im nächsten Update darf nur das "v1.0.6.1" unter AppVerName verändert werden, in diesem Fall erscheint auch keine "wpSelectDir" mehr da Setup beim Start den Pfad aus der Registry ausließt und CODE Zeile 3 immer True ist.
Die Files Sektion ist durch das Flag recursesubdirs stark vereinfacht, das spart enorm Tippaufwand, einfach alle veränderten files recursive nach patch-data kopieren.
Das seperate Flag uninsneveruninstall hinter NehrimLauncher.exe in der Files Sektion sollte, aus gutem Grunde, auch übernommen werden.
Dieses Setup ist schon dual-language vorbereitet, auf einen deutschen Windows erscheinen all Dialoge auf deutsch.
Bei non-German Windows erscheinen alle Dialoge, auch der run dialog und der uninstall record im Startmenü, auf english.
WizardImageFile und WizardSmallImageFile habe ich mir gespart, das muss dann noch per Hand nachträglich eingefügt werden.
Hier File-Upload.net ist das fertige Setup zum ausprobieren.
Important: Zu meinem Selbstschutz habe ich non-admin Rechte in diesem fertigen Setup erzwungen,
falls Nehrim in "Program Files" bzw. "Program Files (x86)" platziert ist kommt einem der Oberaufpasser UAC in die Quere.
Code: Alles auswählen
Im Bild links ist zu sehen wie die files in patch-data liegen müssen, und rechts nochmal das fertige script in Compiler.[Setup]
AppName=Nehrim Update de
AppVerName=Nehrim Update de v1.0.6.1
AppPublisher=Sandmann
AppSupportURL=http://www.sureai.net/forum/viewforum.php?f=76&sid=b0cff0c53439b839de62da893b8ddff3
DefaultDirName={reg:HKCU\Software\SureAI\Nehrim,InstallPath|{src}\..}
DefaultGroupName=Nehrim - Am Rande des Schicksals
OutputBaseFilename=Fixed_NehrimUpdate1061de
Compression=lzma
SolidCompression=yes
DirExistsWarning=no
DisableDirPage=auto
AppendDefaultDirName=no
DisableProgramGroupPage=yes
PrivilegesRequired=poweruser
ShowLanguageDialog=auto
[Code]
procedure OnNewDirEditChange(Sender: TObject);
begin
if DirExists(WizardDirValue() + '\NehrimIcons') then WizardForm.NextButton.Enabled := True else WizardForm.NextButton.Enabled := False;
end;
procedure InitializeWizard;
begin
WizardForm.DirEdit.OnChange := @OnNewDirEditChange;
end;
procedure CurPageChanged(CurrentPageId: integer);
begin
if CurrentPageId = wpSelectDir then begin WizardForm.NextButton.Enabled := false;
OnNewDirEditChange(nil);
end;
end;
[Languages]
Name: en; MessagesFile: compiler:Default.isl
Name: de; MessagesFile: compiler:Languages\German.isl
[Registry]
Root: HKCU; Subkey: Software\SureAI\Nehrim; ValueType: string; ValueName: InstallPath; ValueData: {app}; Flags: uninsdeletevalue
[Files]
Source: f:\images(1)\patch-data\data\*; DestDir: {app}\data; Flags: recursesubdirs
Source: f:\images(1)\patch-data\NehrimLauncher.exe; DestDir: {app}; Flags: uninsneveruninstall
[Icons]
Name: {group}\{cm:UninstallProgram,Nehrim Update de v1.0.6.1}; Filename: {uninstallexe}
[Run]
Filename: {app}\NehrimLauncher.exe; WorkingDir: {app}; Flags: postinstall nowait unchecked; Description: {cm:LaunchProgram,Nehrim Launcher}
Filename: {app}\Oblivion.exe; WorkingDir: {app}; Flags: postinstall nowait unchecked; Description: {cm:LaunchProgram,Nehrim}
