SureAI

Forum around the SureAI game titles.
https://sureai.net/forum/

Enderal Patch 1.1.5.1 + Hotfix 1.1.5.3 veröffentlicht!

https://sureai.net/forum/viewtopic.php?f=119&t=11674

Seite 2 von 2

Re: Enderal Patch 1.1.5.1 + Hotfix 1.1.5.3 veröffentlicht!

Verfasst: 25.11.2016 10:25
von jcdenton99
Auch von mir ein herzliches Dankeschön für den vorbildlichen Support von euch.

Aber hier noch ein Hinweis:
Nach den Konsolenbefehlen werden Statistikeinträge verfälscht sein:
"Groschen Gefunden" wird i.d.R. verdoppelt sein.
"Meiste Groschen besessen" u.U. auch, wenn Geld von der Bank abgehoben wurde "zum Vernichten :P " für den Fix.

Wer gerne auf Statistiken schaut, kann dies bereinigen:
Entweder vorher oder bei laden eines alten Spielstandes die alten Werte aufschreiben.
(Unter Spielmenü -> Statistiken -> Allgemein zu finden)

Den Differenzwert aus aktuellen (falschen) "Groschen Gefunden"-Wert minus korrekten "Groschen Gefunden"-Wert bilden.

Dann mit "^" (links neben der 1-Taste) die Console öffnen und folgenden Befehl eingeben:
ModPCMS "Gold Found" -Differenzwert

Syntax sieht so aus z.B. (fiktiver Zahlenwert):
ModPCMS "Gold Found" -9927


Dasselbe wenn nötig mit den Werten von "Meiste Groschen besessen" durchführen:
ModPCMS "Most Gold Carried" -Differenzwert von "Meiste Groschen besessen"


Ich hoffe, das war einigermassen verständlich von mir ausgedrückt und
es ist keine höhere Mathematik für Euch :wink:


Beste Grüße
JC

Re: Enderal Patch 1.1.5.1 + Hotfix 1.1.5.3 veröffentlicht!

Verfasst: 29.11.2016 21:39
von hati39
Und hier meldet sich wieder der Quengler mit seinem Wunsch, für die Mod Organizer User einen direkten Link zur Verfügung zu stellen :thumbsup:

EDIT:
Weil keiner antwortet, auch nicht auf PMs, hier für die anderen, genervten MO User:
Code: Alles auswählen
http://rs227486.rs.hosteurope.de//files/pro/enderal/upd/de/EnderalUpdate_[1.1.5.0][F][#]_DE.zip
http://rs227486.rs.hosteurope.de//files/pro/enderal/upd/de/EnderalUpdate_[1.1.5.4][S][#]_DE.zip
http://rs227486.rs.hosteurope.de//files/pro/enderal/upd/de/EnderalUpdate_[1.1.5.5][M][1]_DE.zip
http://rs227486.rs.hosteurope.de//files/pro/enderal/upd/de/EnderalUpdate_[1.1.5.6][L][1]_DE.zip

Re: Enderal Patch 1.1.5.1 + Hotfix 1.1.5.3 veröffentlicht!

Verfasst: 14.01.2017 11:51
von Zorg
Tilliboy hat geschrieben:
  • Der Spieler kann nicht mehr alle Schlösser mit Stufe 25 knacken. Im _00E_ChestAndDoorLockScript wurde die Operatoren-Präzedenz zwischen && und || gefixt.
Nur für den Fall, dass ihr es noch nicht bemerkt habt: der Fix hat nicht funktioniert, die Klammern wurden falsch gesetzt.
Hier ein funktionierender Fix (warum kann ich hier keine Datei hochladen?)
Code: Alles auswählen
Scriptname _00E_ChestAndDoorLockScript extends ObjectReference  

Event OnLoad()

	BlockActivation(True)
	
	If _00E_sDoorLocked == None
		_00E_sDoorLocked = Game.GetForm(0x00141570) as Message
	EndIf
	
EndEvent

Event OnHit(ObjectReference akAggressor, Form akSource, Projectile akProjectile, bool abPowerAttack, bool abSneakAttack, bool abBashAttack, bool abHitBlocked)

    Int LockLevel = self.GetLockLevel()

    if akAggressor == PlayerREF
        if (akProjectile == _00E_UnlockProjectile_Novice) && (LockLevel < 2)
            UnlockLock()
        ElseIf ((akProjectile == _00E_UnlockProjectile_Apprentice) && (LockLevel < 26))
            UnlockLock()
        ElseIf ((akProjectile == _00E_UnlockProjectile_Adept) &&  (LockLevel < 51))
            UnlockLock()
        ElseIf ((akProjectile == _00E_UnlockProjectile_Expert) && (LockLevel < 76))
            UnlockLock()
        ElseIf ((akProjectile == _00E_UnlockProjectile_Master) && (LockLevel < 255))
            UnlockLock()
        ElseIf (LockLevel == 255)	
            _00E_sDoorLocked.Show()
            WPNTG06ControlStaffShootFailM.Play(Self)
        EndIf
    EndIf

EndEvent

Event OnActivate(ObjectReference akActionRef)

	Quest qSiegeQuest = Game.GetForm(0x0002EBAD) as Quest
	Location CurrentLoc = Self.GetCurrentLocation()

	If (akActionRef == PlayerREF) && ( CurrentLoc == None || _00E_SuntempleLocations == None || ( _00E_SuntempleLocations != None && CurrentLoc != None && !(_00E_SuntempleLocations.HasForm(CurrentLoc)) ) )
	
		; Debug.MessageBox("ChestAndDoorLockScript is not in suntemple location")
	
		If !(qSiegeQuest.GetStage() >= 5 && qSiegeQuest.GetStage() <= 125)
			If (Self.IsActivationBlocked())
				if (Self.IsLocked() == true) && !(PlayerREF.GetItemCount(Self.GetKey()) > 0)
					Int LockLevel = self.GetLockLevel()
					if (LockLevel <= 25)
						Self.Activate(PlayerREF, True)
					ElseIf (LockLevel > 25) && (LockLevel <= 50) && (PlayerREF.HasPerk(_00E_Class_Trickery_P04b_)  || Game.GetPlayer().GetActorValue("Lockpicking") >= 25)
						Self.Activate(PlayerREF, True)
					ElseIf (LockLevel > 50) && (LockLevel <= 75) && (PlayerREF.HasPerk(_00E_Class_Trickery_P07_) || Game.GetPlayer().GetActorValue("Lockpicking") >= 50)
						Self.Activate(PlayerREF, True)
					ElseIf (LockLevel > 75) && (LockLevel <= 254) && (PlayerREF.HasPerk(_00E_Class_Trickery_P10_) || Game.GetPlayer().GetActorValue("Lockpicking") >= 75)
						Self.Activate(PlayerREF, True)
					ElseIf (LockLevel == 255)
						Self.Activate(akActionRef, True)
					Else
                        if _00E_Game_UnlockNeedsSkill == None
                            ; Hack, because we don't have the time to go over
                            ; all doors in the CK and manually set their
                            ; _00E_Game_UnlockNeedsSkill property.
                            _00E_Game_UnlockNeedsSkill = Game.GetForm(0x00042AE0) as Message
                        endif
                        _00E_Game_UnlockNeedsSkill.Show()
						;Debug.MessageBox(MessageLevelSkill)
					EndIf
				Else
					Self.BlockActivation(False)
					self.Activate(PlayerREF, True)
				EndIf
            EndIf
		Else
			_00E_sDoorLocked.Show()
		EndIf
	Else ;if !(akActionRef == PlayerREF) || (_00E_SuntempleLocations.HasForm(Self.GetCurrentLocation()))
		; Debug.MessageBox("ChestAndDoorLockScript is in suntemple location")
		self.Activate(akActionRef, True)
	EndIf
	
EndEvent

Function UnlockLock()

	Self.Lock(False)
	_00E_UILockpickingUnlockM.Play(Self)
	_00E_Ability_Antimagic_FXSShader.Play(Self)
	self.PlaceAtMe(_00E_UnlockLockExplosion, 1)

EndFunction

Formlist Property _00E_SuntempleLocations Auto

Projectile Property _00E_UnlockProjectile_Novice Auto
Projectile Property _00E_UnlockProjectile_Apprentice Auto
Projectile Property _00E_UnlockProjectile_Adept Auto
Projectile Property _00E_UnlockProjectile_Expert Auto
Projectile Property _00E_UnlockProjectile_Master Auto

Message Property _00E_sDoorLocked Auto
Message Property _00E_sDoorBarricaded Auto

Quest Property MQ12b Auto

Perk Property _00E_Class_Trickery_P04b_ Auto ; Unlock adept locks perk
Perk Property _00E_Class_Trickery_P07_ Auto ; Unlock expert locks
Perk Property _00E_Class_Trickery_P10_ Auto ; Unlock master locks

Sound Property _00E_UILockpickingUnlockM Auto
Sound Property WPNTG06ControlStaffShootFailM Auto

EffectShader Property _00E_Ability_Antimagic_FXSShader Auto
Explosion Property _00E_UnlockLockExplosion Auto

Actor Property PlayerREF Auto
;String MessageLevelSkill = "Eure Fähigkeiten reichen nicht aus um dieses Schloss zu knacken! Erhöht eure Fähigkeit in Schlösserknacken oder entsprechende Erinnerungstalente für Schlösserknacken!"

Message Property _00E_Game_UnlockNeedsSkill Auto

Re: Enderal Patch 1.1.5.1 + Hotfix 1.1.5.3 veröffentlicht!

Verfasst: 14.01.2017 14:27
von Nicolas Samuel
Wo wurden denn die Klammern falsch gesetzt? Entweder das Script war nicht im Patch oder ich hab gründlich was übersehen - ich hab das gefühlte zwanzig Mal getestet, und bei mir funktionierte das Script wie beabsichtigt.

Edit: Ah, sehe gerade, zu beziehst dich auf den alten Patch. Im nächsten ist das gefixt. War etwas verwirrt.

Re: Enderal Patch 1.1.5.1 + Hotfix 1.1.5.3 veröffentlicht!

Verfasst: 14.01.2017 15:18
von stuemper
Danke @Zorg, aber das war uns schon eine Weile bekannt (~Weihnachten '16) und gefixt, nur noch nicht gepatcht. ;)
Alle Zeiten sind UTC
Seite 2 von 2
Powered by phpBB® Forum Software © phpBB Limited
https://www.phpbb.com/